import crafttweaker.item.IItemStack;

val russianItem = <flansmod:russian_item>;
val gunpowderBlock = <flansmod:gunpowderblock>;
val dandelionYellow = <minecraft:dye:11>;
val roseRed = <minecraft:dye:1>;

val ironShovel = <minecraft:iron_shovel>;
val ironHoe = <minecraft:iron_hoe>;
val ironPickaxe = <minecraft:iron_pickaxe>;
val ironAxe = <minecraft:iron_axe>;
val diamondShovel = <minecraft:diamond_shovel>;
val diamondHoe = <minecraft:diamond_hoe>;
val diamondPickaxe = <minecraft:diamond_pickaxe>;
val diamondAxe = <minecraft:diamond_axe>;

val antimatterExplosives = <icbmclassic:explosives:22>;
val antimatterMissile = <icbmclassic:explosive_missile:22>;
val tier10Rocket = <extraplanets:item_tier10_rocket:3>;

val moxFuel = <ic2:quad_mox_fuel_rod>;
val mfsu = <ic2:te:75>;
val nuclearMissile = <icbmclassic:explosives:15>;

val nuclearReactor = <ic2:te:22>;
val nuclearChamber = <ic2:te:24>;
val advancedMachineCasing = <ic2:resource:13>;
val advancedCircuit = <ic2:crafting:2>;
val uranium235 = <ic2:nuclear:1>;
val enrichedUraniumNuclearFuel = <ic2:nuclear:0>;
val moxNuclearFuel = <ic2:nuclear:4>;
val plutonium = <ic2:nuclear:3>;
val reactorPlating = <ic2:plating:0>;
val advancedAlloy = <ic2:crafting:3>;
val rtgPellets = <ic2:nuclear:10>;

val heavyDutyPlatingT1 = <galacticraftcore:heavy_plating:0>;

val stableUnstableNugget = <extrautils2:unstableingots:1>;
val stableUnstableIngot = <extrautils2:unstableingots:2>;
val unstableIngot = <extrautils2:unstableingots:0>;

val tools = [
    <minecraft:iron_shovel>,
    <minecraft:iron_hoe>,
    <minecraft:iron_pickaxe>,
    <minecraft:iron_axe>,
    <minecraft:diamond_shovel>,
    <minecraft:diamond_hoe>,
    <minecraft:diamond_pickaxe>,
    <minecraft:diamond_axe>
] as IItemStack[];

function setDurabilityAndTooltip(item as IItemStack) as void {
    item.maxDamage = 2;  
    item.addTooltip(format.red("This tool is useless, use Tinkers' Construct")); 
}

for tool in tools {
    setDurabilityAndTooltip(tool);
}

recipes.remove(russianItem);
recipes.remove(antimatterExplosives);
recipes.remove(antimatterMissile);
recipes.remove(nuclearReactor);
recipes.remove(nuclearChamber);
recipes.remove(stableUnstableIngot);
recipes.remove(stableUnstableNugget);
recipes.remove(enrichedUraniumNuclearFuel);
recipes.remove(moxNuclearFuel);
recipes.remove(reactorPlating);
recipes.remove(rtgPellets);

recipes.addShapeless(reactorPlating, [heavyDutyPlatingT1, advancedAlloy]);

recipes.addShaped(rtgPellets, [
    [plutonium, plutonium, plutonium],
    [plutonium, plutonium, plutonium],
    [plutonium, plutonium, plutonium]
]);

recipes.addShaped(enrichedUraniumNuclearFuel, [
    [uranium235, uranium235, uranium235],
    [uranium235, uranium235, uranium235],
    [uranium235, uranium235, uranium235]
]);

recipes.addShaped(moxNuclearFuel, [
    [uranium235, uranium235, uranium235],
    [plutonium, plutonium, plutonium],
    [uranium235, uranium235, uranium235]
]);

recipes.addShaped(nuclearChamber, [
    [heavyDutyPlatingT1, heavyDutyPlatingT1, heavyDutyPlatingT1],
    [heavyDutyPlatingT1, advancedMachineCasing, heavyDutyPlatingT1],
    [heavyDutyPlatingT1, heavyDutyPlatingT1, heavyDutyPlatingT1]
]);

recipes.addShaped(nuclearReactor, [
    [unstableIngot, advancedCircuit, unstableIngot],
    [nuclearChamber, nuclearChamber, nuclearChamber],
    [unstableIngot, advancedMachineCasing, unstableIngot]
]);

recipes.addShaped(antimatterMissile, [
    [tier10Rocket, tier10Rocket, tier10Rocket],
    [tier10Rocket, antimatterExplosives, tier10Rocket],
    [tier10Rocket, tier10Rocket, tier10Rocket]
]);

recipes.addShaped(antimatterExplosives, [
    [tier10Rocket, mfsu, tier10Rocket],
    [nuclearMissile, nuclearMissile, nuclearMissile],
    [tier10Rocket, mfsu, tier10Rocket]
]);

recipes.addShaped(russianItem, [
    [gunpowderBlock, gunpowderBlock, gunpowderBlock],
    [dandelionYellow, roseRed, roseRed],
    [gunpowderBlock, gunpowderBlock, gunpowderBlock]
]);